JCL_print_toPDF

PDFファイルを作成する。

使い方
JCL_print_toPDF([PERIOD]->;”A01BSA_Pirnt”;”PE10_Print”)

引数
$1: 作成するPDFのファイルパス。プラットフォームパスで与える（POSIXは不可）
$2: テーブルへのポインタ
$3: テーブルフォームの名前

プロジェクトフォームには対応していない。ソースを修正して使う。

//JCL_print_toPDF
//20251008 wat
//テーブルフォームを使って、Print formでPDFに出力。OPEN PRINTING JOBで囲むようにして、モジュール化

C_TEXT($1; $pdf_path)
$pdf_path:=$1
C_POINTER($2;$tblPtr)
$tblPtr:=$2
C_TEXT($3;$frmName)
$frmName:=$3
C_TEXT($pdfprintername)

If (Is macOS)
	//macOS
	SET PRINT OPTION(Destination option; 3; $pdf_path)
	
	OPEN PRINTING JOB
	Print form($tblPtr->; $frmName; Form detail)
	CLOSE PRINTING JOB
	
Else 
	//Windows
	$pdfprintername:="Microsoft Print to PDF"
	ARRAY TEXT($aryPrinterName; 0)
	PRINTERS LIST($aryPrinterName)
	If (Find in array($aryPrinterName; $pdfprintername)>0)
		SET CURRENT PRINTER($pdfprintername)
		SET PRINT OPTION(Destination option; 2; $pdf_path)
		
		OPEN PRINTING JOB
		Print form($tblPtr->; $frmName; Form detail)
		CLOSE PRINTING JOB
		
		SET CURRENT PRINTER("")
	End if 
End if